pkgname=pixman
pkgver=0.46.4
pkgdesc="The pixel-manipulation library for X and cairo"
arch=(x86_64)
homepage="https://gitlab.freedesktop.org/pixman/pixman"
license=('MIT')
depends=('glibc')
makedepends=('meson')
sources=("${pkgname}-${pkgver}.tar.xz")
urls=("https://www.x.org/releases/individual/lib/${sources[0]}")
md5sums=("f0b949cfe21fe59ac4457c57ddb7b9e5")

src_prepare() {
  tar -xf ${distdir}/${sources[0]} --strip-components=1
}

src_build() {
  local _mesonopts=(
    --prefix=/usr
    --buildtype=release
    -D loongson-mmi=disabled
    -D vmx=disabled
    -D arm-simd=disabled
    -D neon=disabled
    -D mips-dspr2=disabled
    -D rvv=disabled
    -D gtk=disabled
    -D sse2=enabled
    -D ssse3=enabled
    -D mmx=enabled
    -D default_library=shared
    -D libpng=disabled
    -D demos=disabled
  )
  meson setup build "${_mesonopts[@]}"
  meson compile -C build
}

src_check() {
  meson test -C build
}

src_install() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
}

# vim:ft=sh syn=sh et sw=2:
