pkgname=yasm
pkgver=1.3.0
pkgdesc="A rewrite of NASM to allow for multiple syntax supported (NASM, TASM, GAS, etc.)"
arch=('x86_64')
homepage='https://github.com/yasm/yasm'
license=('BSD-2-Clause OR BSD-3-Clause' 'GPL-2.0-only' 'LGPL-2.1-only' 'Artistic-1.0-Perl')
depends=('glibc')
makedepends=('git' 'python' 'xmlto')
sources=("${pkgname}-${pkgver}.tar.gz"
  "yasm-1.3.0-fix-modern-c.patch"
)
urls=("https://www.tortall.net/projects/yasm/releases/${sources[0]}"
  "yasm-1.3.0-fix-modern-c.patch"
)
md5sums=("fc9e586751ff789b34b1f21d572d96af"
  "4632ef400355360368752da974dcc31a"
)

src_prepare() {
  tar -xf ${distdir}/${sources[0]} --strip-components=1
  patch -p1 -i ${filedir}/${sources[1]}
}

src_build() {
  CFLAGS+=" -std=gnu17"
  ./configure --prefix=/usr \
    --disable-warnerror \
    --disable-python \
    --disable-python-bindings \
    --enable-nls
  make
}

src_check() {
  make -j1 check
}

src_install() {
  make DESTDIR="${pkgdir}" install

  # licenses
  install -vDm644 \
    -t "$pkgdir/usr/share/licenses/$pkgname" \
    {Artistic,BSD}.txt COPYING GNU_*
}

# vim:ft=sh syn=sh et sw=2:
