pkgname=glibmm
pkgver=2.66.8
_ver=${pkgver%.*}
pkgdesc="C++ bindings for GLib"
homepage="https://www.gtkmm.org/"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  gcc
  glib:2
  glibc
  libsigc++:2
)
makedepends=(
  clang
  meson
)
sources=("${pkgname}-${pkgver}.tar.xz")
urls=("https://download.gnome.org/sources/${pkgname}/${_ver}/${sources[0]}")
sha512sums=("4ebf203324d3ee95c47012915efb39d4dc59eb7a6f337e7b8c7c0b3589574b07967974363931b0d4159618f88178b04715b2c359c3dc3f67a7781bfac0d9f277")

src_prepare() {
  tar -xf ${distdir}/${sources[0]} --strip-components=1
}

src_build() {
  local meson_args=(
    --prefix=/usr
    --buildtype=release
    --wrap-mode=nodownload
    -D python.bytecompile=1
    -D warnings=min
    -D build-deprecated-api=true
    -D build-documentation=false
    -D debug-refcounting=false
    -D build-examples=false
  )
  meson setup build "${meson_args[@]}"
  meson compile -C build
}

src_install() {
  meson install -C build --destdir "$pkgdir"
}

# vim:ft=sh syn=sh et sw=2:
