pkgname=rofi
pkgver=2.0.0
pkgdesc="A window switcher, application launcher and dmenu replacement"
homepage="https://davatorium.github.io/rofi"
arch=('x86_64')
license=('MIT')
depends=('bash' 'cairo' 'gdk-pixbuf:2' 'glib:2' 'glibc' 'libxkbcommon' 'pango' 'wayland')
makedepends=('meson' 'pandoc' 'wayland-protocols')
sources=("${pkgname}-${pkgver}.tar.xz")
urls=("https://github.com/davatorium/rofi/releases/download/${pkgver}/${sources[0]}")
sha512sums=("0531f7da2a6e363b2c97c47778cadc4a84eb58903ea91ce683ff98d7c6e23172fa0df59a42f7236a4a0e80020c21c72cbc126ffe260491082ab9cc19ef6673d5")

src_prepare() {
  tar -xf ${distdir}/${sources[0]} --strip-components=1
}

src_build() {
  local meson_args=(
    --prefix=/usr
    --buildtype=release
    --wrap-mode=nodownload
    -D python.bytecompile=1
    -D drun=true
    -D window=true
    -D check=disabled
    -D wayland=enabled
    -D xcb=disabled
    -D imdkit=false
  )
  meson setup build "${meson_args[@]}"
  meson compile -C build
}

src_install() {
  meson install -C build --destdir "$pkgdir"
}

# vim:ft=sh syn=sh et sw=2:
