pkgname=tiff
pkgver=4.7.0
pkgdesc='Library for manipulation of TIFF images'
homepage='http://www.simplesystems.org/libtiff/'
arch=(x86_64)
license=(libtiff)
depends=(
  gcc-libs
  glibc
  libjpeg-turbo
  xz
  zlib
  zstd
)
makedepends=(cmake)
sources=("${pkgname}-${pkgver}.tar.gz")
urls=("https://download.osgeo.org/libtiff/${sources[0]}")
md5sums=("3a0fa4a270a4a192b08913f88d0cfbdd")

src_prepare() {
  tar -xf ${distdir}/${sources[0]} --strip-components=1
}

src_build() {
  local confargs=(
    --prefix=/usr
    --disable-sphinx
    --with-docdir=/usr/share/doc/${pkgname}-${pkgver}
    --enable-cxx
    --disable-jbig
    --enable-jpeg
    --disable-opengl
    --disable-lerc
    --disable-libdeflate
    --disable-lzma
    --disable-static
    --disable-webp
    --enable-zlib
    --enable-zstd
    --enable-contrib
    --enable-tools
  )
  ./configure "${confargs[@]}"
  make
}

src_check() {
  make check
}

src_install() {
  make DESTDIR="${pkgdir}" install
  rm -vf "${pkgdir}"/usr/share/doc/${pkgname}-${pkgver}/{README*,RELEASE-DATE,TODO,VERSION}
}

# vim:ft=sh syn=sh et sw=2:
