pkgname=aquamarine
pkgver=0.8.0
pkgdesc='a very light linux rendering backend library'
arch=(x86_64 aarch64)
url="https://github.com/hyprwm/$pkgname"
license=(BSD-3-Clause)
depends=(gcc-libs
         glibc
         hyprutils
         hyprwayland-scanner
         libdisplay-info
         libdrm
         libglvnd
         libinput
         mesa # libgbm.so
         pixman
         seatd
         systemd
         wayland
         wayland-protocols)
makedepends=(cmake)
sources=("${pkgname}-${pkgver}.tar.gz")
urls=("https://github.com/hyprwm/${pkgname}/archive/v${pkgver}.tar.gz")
md5sums=("b573d36528d2548d3ffa0e572da5f347")

src_prepare() {
  tar -xf ${distdir}/${sources[0]} --strip-components=1
  sed -i "/add_compile_options(-O3)/d" "CMakeLists.txt"
}

src_build() {
  cmake -B build \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D CMAKE_BUILD_TYPE=Release
  cmake --build build
}

src_install() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}

# vim:ft=sh syn=sh et sw=2: