new bblfs: sys-fs/duf-0.9.1

app-misc/yazi-25.5.31.PKGBUILD

@@ -0,0 +1,42 @@
+pkgname=yazi
+pkgver=25.5.31
+pkgdesc="Blazing fast terminal file manager written in Rust, based on async I/O."
+homepage="https://yazi-rs.github.io"
+license=("MIT")
+depends=("oniguruma")
+sources=("${pkgname}-${pkgver}.tar.gz")
+urls=("https://github.com/sxyazi/yazi/archive/refs/tags/v${pkgver}.tar.gz")
+sha512sums=("c390d3e813cbefbe5c430df521f7d563aff8461eb249a90a11fba05db56205bfce5df0f15ae7a57aa8a47cff34094b969fe6fbdfa9cd9a102dba3b8cc9c30911")
+
+src_prepare() {
+  tar -xf ${distdir}/${sources[0]} --strip-components=1
+  sed -i -r 's/strip\s+= true/strip = false/' Cargo.toml
+  cargo fetch --locked --target "$(rustc --print host-tuple)"
+}
+
+src_build() {
+  export YAZI_GEN_COMPLETIONS=true
+  export RUSTONIG_SYSTEM_LIBONIG=1
+  cargo build --frozen --release --no-default-features
+}
+
+_install_completions() {
+  pushd "$1/completions"
+  install -Dm644 "$2.bash" "$pkgdir/usr/share/bash-completion/completions/$2"
+  install -Dm644 "$2.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d/"
+  install -Dm644 "_$2" -t "$pkgdir/usr/share/zsh/site-functions/"
+  popd
+}
+
+src_install() {
+  install -Dm755 "target/release/$pkgname" -t "$pkgdir/usr/bin/"
+  install -Dm755 "target/release/ya" -t "$pkgdir/usr/bin/"
+  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/$pkgname-${pkgver}/"
+  install -Dm644 "assets/yazi.desktop" -t "$pkgdir/usr/share/applications/"
+
+  _install_completions "$pkgname-boot" "$pkgname"
+  _install_completions "$pkgname-cli" "ya"
+}
+
+# vim:ft=sh syn=sh et sw=2:

dev-lang/lua-5.1.5.PKGBUILD

@@ -0,0 +1,30 @@
+pkgname=lua
+pkgver=5.1.5
+_majorver=${pkgver%.*}
+pkgdesc='Powerful lightweight programming language designed for extending applications'
+arch=('x86_64')
+homepage='https://www.lua.org/'
+depends=('readline')
+license=('MIT')
+sources=("${pkgname}-${pkgver}.tar.xz")
+urls=("https://dev.gentoo.org/~soap/distfiles/${sources[0]}")
+sha512sums=("bd827cb2e63cd71d15d846eb29c8745bf869e7b70e12c565ce173623d1fcd29dabf4d33a99c48f294151bb580d830c112cf178e2d80a5a5c36acc7b3bfcd7d24")
+
+src_prepare() {
+  tar -xf ${distdir}/${sources[0]} --strip-components=1
+}
+
+src_build() {
+  ./configure --prefix=/usr --with-readline --docdir="/usr/share/doc/${pkgname}-${pkgver}"
+  make
+}
+
+src_check() {
+  make check
+}
+
+src_install() {
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:ft=sh syn=sh et sw=2:

dev-lang/lua-5.4.8.PKGBUILD

@@ -15,7 +15,7 @@ src_prepare() {
 }
 
 src_build() {
-  ./configure --prefix=/usr --with-readline
+  ./configure --prefix=/usr --with-readline --docdir="/usr/share/doc/${pkgname}-${pkgver}"
   make
 }
 

media-video/mpv-0.41.0.PKGBUILD

@@ -0,0 +1,113 @@
+pkgname=mpv
+pkgver=0.41.0
+pkgdesc="Media player for the command line"
+homepage="https://mpv.io/"
+license=("LGPL-2.1+" "GPL-2+" "BSD" "ISC" "MIT")
+depends=(
+  libass
+  libplacebo
+  ffmpeg
+  libdisplay-info
+  libdrm
+  "mesa[gbm]"
+  libglvnd
+  "libplacebo[opengl]"
+  "lua:5.1"
+  pipewire
+  libpulse
+  app-i18n/uchardet
+  libva
+  vulkan-loader
+  wayland
+  libxkbcommon
+  zlib
+  vulkan-headers
+  wayland-protocols
+)
+bdepends=(meson docutils wayland-scanner)
+sources=("${pkgname}-${pkgver}.tar.gz")
+urls=("https://github.com/mpv-player/mpv/archive/v${pkgver}.tar.gz")
+sha512sums=("d8806ef04455aeb65d45c5956b4589d7a9728f869b74b9bcd8c9ab08475c28538334399ddc7fc2aee6a31fd178fe4b87ec755cd99ffa6e29ab4b6b61757b9320")
+
+src_prepare() {
+  tar -xf ${distdir}/${sources[0]} --strip-components=1
+}
+
+src_build() {
+  local meson_args=(
+    --prefix=/usr
+    --buildtype=release
+    --wrap-mode=nodownload
+    -D python.bytecompile=1
+
+    -D cplayer=true
+    -D libmpv=true
+    -D tests=false
+
+    -D html-build=enabled
+    -D manpage-build=enabled
+    -D pdf-build=disabled
+    -D build-date=false
+
+    -D x11-clipboard=disabled
+    -D libarchive=disabled
+    -D libbluray=disabled
+    -D cdda=disabled
+    -D cplugins=enabled
+    -D dvbin=disabled
+    -D dvdnav=disabled
+    -D sdl2-gamepad=disabled
+    -D iconv=enabled
+    -D javascript=disabled
+    -D libavdevice=enabled
+    -D lcms2=disabled
+    -D lua=enabled
+    -D rubberband=disabled
+    -D uchardet=enabled
+    -D vapoursynth=disabled
+    -D zimg=disabled
+    -D zlib=enabled
+
+    # audio output
+    -D alsa=disabled
+    -D coreaudio=disabled
+    -D jack=disabled
+    -D openal=disabled
+    -D pipewire=enabled
+    -D pulse=enabled
+    -D sdl2-audio=disabled
+    -D sndio=disabled
+
+    # video output
+    -D x11=disabled
+    -D cocoa=disabled
+    -D drm=enabled
+    -D jpeg=disabled
+    -D caca=disabled
+    -D sdl2-video=disabled
+    -D sixel=disabled
+    -D wayland=enabled
+    -D xv=disabled
+
+    -D gl=enabled
+    -D egl=enabled
+    -D plain-gl=enabled
+    -D gl-x11=disabled
+    -D vulkan=enabled
+    -D cuda-hwaccel=disabled
+    -D vaapi=enabled
+    -D vdpau=disabled
+  )
+  meson setup build "${meson_args[@]}"
+  meson compile -C build
+}
+
+src_install() {
+  meson install -C build --destdir "$pkgdir"
+
+  cp -r TOOLS/lua "${pkgdir}/usr/share/${pkgname}"
+
+  mv -v "${pkgdir}"/usr/share/doc/${pkgname}{,-${pkgver}}
+}
+
+# vim:ft=sh syn=sh et sw=2:

media-video/pipewire-1.4.9.PKGBUILD

@@ -34,18 +34,21 @@ sources=("${pkgname}-${pkgver}.tar.bz2"
   "${pkgname}-1.4.7-0001-don-t-include-standard-C-headers-inside-of-extern-C.patch.xz"
   "99-pipewire-default-hook.conf"
   "acct-group-pipewire.conf"
+  "gentoo-sound-server-enable-audio-bluetooth.conf"
   ${_patches[@]}
 )
 urls=("https://gitlab.freedesktop.org/${pkgname}/${pkgname}/-/archive/${pkgver}/${sources[0]}"
   "https://dev.gentoo.org/~sam/distfiles/media-video/${pkgname}/${sources[1]}"
   "99-pipewire-default-hook.conf"
   "acct-group-pipewire.conf"
+  "gentoo-sound-server-enable-audio-bluetooth.conf"
   "${_patches[@]}"
 )
 sha512sums=("369054d920133904a8df709b1be05f9ef0e7e99e1ae10e1d200315ce1200e20d5e20a91f40dd17dd3177eef59de7d47dfdd6161ec6f057b78140690fcfcc1c2e"
   "fbd9644a5df81ee4bc9687f6a8b69a0bf12deef43d749c9c5cbb976f461771deeae4bd13340a6acaffae4b0187221cf734be2b3b62408a4ce79d70575a7e664b"
   "4e512c62b7627fbe9e48afbbf171bd2b8d4fb8b231492cb1ea2d90ac474212c25e0f8ba3389b1df1108a46f243f2e1f3a3eaf2d147a7968cec82a8a49f5fd1b7"
   "65901c2bef4c769757631487231d43d4bc584c9202d280179696736e4985b195f14ab5a935d59d36f67cfa094e6749ac1f1d1aa2e9943ca746415eb1ff550b69"
+  "fede2c9dc6256894aa29cf72ede8ba42874cf0706d81031d724ca5b43fa424d09009ec6eb685737623f3c5eadb9b095060b0ce48b7325d68d4b07225b07aa2fe"
   "${_patch_sums[@]}"
 )
 
@@ -157,6 +160,8 @@ src_install() {
   ln -sv ../../../usr/share/alsa/alsa.conf.d/50-pipewire.conf "${pkgdir}"/etc/alsa/conf.d/50-pipewire.conf
   ln -sv ../../../usr/share/alsa/alsa.conf.d/99-pipewire-default-hook.conf "${pkgdir}"/etc/alsa/conf.d/99-pipewire-default-hook.conf
 
+  install -vDm644 "${filedir}/gentoo-sound-server-enable-audio-bluetooth.conf" -t "${pkgdir}/etc/wireplumber/wireplumber.conf.d"
+
   install -vDm644 "${filedir}/acct-group-pipewire.conf" -t "${pkgdir}/usr/lib/sysusers.d/"
 }
 

media-video/pipewire/gentoo-sound-server-enable-audio-bluetooth.conf

@@ -0,0 +1,6 @@
+wireplumber.profiles = {
+  main = {
+    hardware.audio = required
+    hardware.bluetooth = required
+  }
+}

sys-apps/cyme-2.2.10.PKGBUILD

@@ -0,0 +1,36 @@
+pkgname=cyme
+pkgver=2.2.10
+pkgdesc="List system USB buses and devices; a modern cross-platform \`lsusb\`"
+homepage="https://github.com/tuna-f1sh/cyme/"
+license=("GPL-3+")
+sources=("${pkgname}-${pkgver}.tar.gz")
+urls=("https://github.com/tuna-f1sh/cyme/archive/v${pkgver}.tar.gz")
+sha512sums=("6a122be9a0bdbbc27fb44406b6ee1123215ef93be9926f6e3b939f0836ec96f46f709d46483b936291dc1730af5468b61eb2597f640d8cc7aac451791949efc4")
+
+src_prepare() {
+  tar -xf ${distdir}/${sources[0]} --strip-components=1
+  cargo fetch --locked --target "$(rustc --print host-tuple)"
+}
+
+src_build() {
+  cargo build --frozen --release --all-features
+}
+
+src_check() {
+  cargo test --frozen
+}
+
+src_install() {
+  install -Dm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/README.md"
+  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+  cd "doc"
+  install -Dm644 "${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+
+  install -Dm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
+  install -Dm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
+  install -Dm644 "_${pkgname}" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
+}
+
+# vim:ft=sh syn=sh et sw=2:

sys-apps/lshw-02.20.2b.PKGBUILD

@@ -0,0 +1,28 @@
+pkgname=lshw
+pkgver=02.20.2b
+_ver=B.02.20
+pkgdesc="Hardware Lister"
+homepage="https://www.ezix.org/project/wiki/HardwareLiSter"
+license=("GPL-2")
+depends=(hwdata)
+_patches=("lshw-02.19.2b-respect-LDFLAGS.patch")
+sources=("${pkgname}-${_ver}.tar.gz")
+urls=("https://www.ezix.org/software/files/${sources[0]}")
+sha512sums=("afc5d57f4b7c49d8e1934a3df623657882cc1325268c8c024dc0fa25495edd3ce7fdadb9c83ac6e5d3e723bc08d6175162d4d879ced09f76ad145ff42b38d3f0")
+
+src_prepare() {
+  tar -xf ${distdir}/${sources[0]} --strip-components=1
+  for _patch in ${_patches[@]}; do
+    patch -p1 -i ${filedir}/${_patch}
+  done
+}
+
+src_build() {
+  make VERSION=${_ver} SQLITE=0 SBINDIR=/usr/bin
+}
+
+src_install() {
+  make DESTDIR="$pkgdir"/ SBINDIR=/usr/bin install
+}
+
+# vim:ft=sh syn=sh et sw=2:

sys-apps/lshw/lshw-02.19.2b-respect-LDFLAGS.patch

@@ -0,0 +1,33 @@
+diff --git a/src/Makefile b/src/Makefile
+index 7ae8218..5c990b0 100644
+--- a/src/Makefile
++++ b/src/Makefile
+@@ -30,7 +30,7 @@ endif
+ ifeq ($(ZLIB), 1)
+ 	CXXFLAGS+= -DZLIB $(shell pkg-config --cflags zlib)
+ endif
+-LDFLAGS+=-L./core/ -g
++LIBS+=-L./core/
+ ifneq ($(shell $(LD) --help 2| grep -- --as-needed), )
+ 	LDFLAGS+= -Wl,--as-needed
+ endif
+@@ -44,7 +44,6 @@ ifeq ($(ZLIB), 1)
+ endif
+ 
+ export CXXFLAGS
+-export LIBS
+ export LDFLAGS
+ 
+ ifeq ($(ZLIB), 1)
+diff --git a/src/gui/Makefile b/src/gui/Makefile
+index 63c4ff5..7946736 100644
+--- a/src/gui/Makefile
++++ b/src/gui/Makefile
+@@ -18,7 +18,6 @@ LIBS+=-L../core -llshw -lresolv $(GTKLIBS)
+ ifeq ($(SQLITE), 1)
+ 	LIBS+= $(shell pkg-config --libs sqlite3)
+ endif
+-LDFLAGS=
+ ifneq ($(shell $(LD) --help 2| grep -- --as-needed), )
+ 	LDFLAGS+= -Wl,--as-needed
+ endif

sys-fs/duf-0.9.1.PKGBUILD

@@ -0,0 +1,36 @@
+pkgname=duf
+pkgver=0.9.1
+pkgdesc="Disk Usage/Free Utility - a better 'df' alternative"
+homepage="https://github.com/muesli/duf"
+license=("MIT" "BSD" "Apache-2.0")
+sources=("${pkgname}-${pkgver}.tar.gz")
+bdepends=("go")
+urls=("https://github.com/muesli/duf/archive/refs/tags/v${pkgver}.tar.gz")
+sha512sums=("5ebb8b8800268f97590488307c83f7adcd133339e5f2b86d26903b112ab826fefc66175c0f03e23b6ac1a7ebe81c416bb44f302e459b36cae6fe50279345d203")
+
+src_prepare() {
+  tar -xf ${distdir}/${sources[0]} --strip-components=1
+}
+
+src_build() {
+  local commit=$(zcat ${distdir}/${sources[0]} | git get-tar-commit-id)
+  local extraflags="-X main.Version=$pkgver -X main.CommitSHA=$commit"
+	export CGO_CPPFLAGS="$CPPFLAGS"
+	export CGO_CFLAGS="$CFLAGS"
+	export CGO_CXXFLAGS="$CXXFLAGS"
+  go build \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-linkmode external $extraflags -extldflags \"$LDFLAGS\"" \
+    -o "$pkgname" .
+}
+
+src_install() {
+  install -Dm0755 -t "$pkgdir/usr/bin/" "$pkgname"
+  install -Dm0644 -t "$pkgdir/usr/share/man/man1/" "$pkgname.1"
+  install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+# vim:ft=sh syn=sh et sw=2: